The Alternative Csound Reference Manual
Previous |  | Next

# flanger

flanger -- A user controlled flanger.

## Description

A user controlled flanger.

## Syntax

ar flanger asig, adel, kfeedback [, imaxd]

## Initialization

imaxd(optional) -- maximum delay in seconds (needed for inital memory allocation)

## Performance

asig -- input signal

adel -- delay in seconds

kfeedback -- feedback amount (in normal tasks this should not exceed 1, even if bigger values are allowed)

This unit is useful for generating choruses and flangers. The delay must be varied at a-rate connecting adel to an oscillator output. Also the feedback can vary at k-rate. This opcode is implemented to allow kr different than sr (else delay could not be lower than ksmps) enhancing realtime performance. This unit is very similar to wguide1, the only difference is flanger does not have the lowpass filter.

## Examples

Here is an example of the flanger opcode. It uses the files flanger.orc, flanger.sco, and beats.wav.

Example 1. Example of the flanger opcode.

    /* flanger.orc */
    ; Initialize the global variables.
    sr = 44100
    kr = 4410
    ksmps = 10
    nchnls = 1

    ; Instrument #1.
    instr 1
      ; Use the "beat.wav" audio file.
      asig soundin "beats.wav"

      ; Vary the delay amount from 0 to 0.01 seconds.
      adel line 0, p3, 0.01
      kfeedback = 0.7

      ; Apply flange to the input signal.
      aflang flanger asig, adel, kfeedback

      ; It can get loud, so clip its amplitude to 30,000.
      a1 clip aflang, 1, 30000
      out a1
    endin
    /* flanger.orc */

    /* flanger.sco */
    ; Play Instrument #1 for two seconds.
    i 1 0 2
    e
    /* flanger.sco */

## Credits

Author: Gabriel Maldonado
Italy

Example written by Kevin Conder.

New in Csound version 3.49

Previous | Home | Next
fiopen | Up | flashtxt