AC_INIT
AM_INIT_AUTOMAKE([fastresolve], [2.10])
AC_PATH_PROGS(PERL, [perl5 perl], [/usr/bin/perl])
AC_PROG_CC
AC_PROG_CXX
AC_CHECK_FUNCS(fgetln)

# The following macro is
#    Copyright (C) 1997-1999 Ian Jackson <ian@davenant.greenend.org.uk>
# distributed under the GNU GPL (v2+).
AC_DEFUN(ADNS_C_GETFUNC,[
 AC_CHECK_FUNC([$1],,[
  AC_CHECK_LIB([$2],[$1],[$3],[
    AC_MSG_ERROR([cannot find library function $1])
  ])
 ])
])

ADNS_C_GETFUNC(socket,socket)
ADNS_C_GETFUNC(inet_ntoa,nsl)
ADNS_C_GETFUNC(inet_aton,resolv,[LIBS="-lresolv $LIBS"])
AC_CHECK_LIB(z, gzprintf, , AC_MSG_ERROR([zlib including gzprintf is required]))
AC_CHECK_LIB(adns, adns_submit, , AC_MSG_ERROR([adns library is required]))

AC_DEFUN(DJM_LIB_DB_CXX,
[dnl Check for a C++ interface, either version.

AC_ARG_WITH(bdb-lib,
    [  --with-bdb-lib=PATH	Path to Berkeley DB C++ library],
    with_bdb_lib=$withval,
    [ test "${with_bdb_lib+set}" = set || with_bdb_lib=none])
AC_ARG_WITH(bdb-incdir,
    [  --with-bdb-incdir=DIR	Berkeley DB C++ includes are in DIR],
    with_bdb_incdir=$withval,
    [ test "${with_bdb_incdir+set}" = set || with_bdb_incdir=none])

if test $with_bdb_incdir != none; then
CXXFLAGS="$CXXFLAGS -I$with_bdb_incdir"
fi

if test $with_bdb_lib != none; then

dnl Berkeley DB from supplied path
AC_MSG_CHECKING([for Db::open in ${with_bdb_lib}])
AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS $with_bdb_lib"
AC_TRY_LINK([#include <db_cxx.h>], [Db *d = new Db(NULL, 0);],
	djm_cv_lib_bdb_cxx_Db=yes, djm_cv_lib_bdb_cxx_Db=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE
AC_MSG_RESULT($djm_cv_lib_bdb_cxx_Db)

if test $djm_cv_lib_bdb_cxx_Db = yes; then
	LIBS="$LIBS $with_bdb_lib"
else
	AC_MSG_ERROR([Berkeley DB library 2.x-4.x configured with --enable-cxx is required])
fi

else

dnl Berkeley DB 2.x.
AC_CACHE_CHECK([for Db::open in -ldb], djm_cv_lib_db_Dbopen,
[AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS -ldb"
AC_TRY_LINK([#include <db_cxx.h>], [Db::open(NULL, DB_BTREE, DB_CREATE, 0, NULL, NULL, NULL);],
	djm_cv_lib_db_Dbopen=yes, djm_cv_lib_db_Dbopen=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE])

if test $djm_cv_lib_db_Dbopen = yes; then
	LIBS="$LIBS -ldb"
else


dnl Berkeley DB 3.x or 4.x installed as libdb.
AC_CACHE_CHECK([for Db in -ldb_cxx], djm_cv_lib_db_cxx_Db,
[AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS -ldb -ldb_cxx"
AC_TRY_LINK([#include <db_cxx.h>], [Db *d = new Db(NULL, 0);],
	djm_cv_lib_db_cxx_Db=yes, djm_cv_lib_db_cxx_Db=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE])

if test $djm_cv_lib_db_cxx_Db = yes; then
	LIBS="$LIBS -ldb -ldb_cxx"
else

dnl Berkeley DB 3.x installed as libdb3 (as on FreeBSD).
AC_CACHE_CHECK([for Db in -ldb3_cxx], djm_cv_lib_db3_cxx_Db,
[AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS -ldb3 -ldb3_cxx"
AC_TRY_LINK([#include <db_cxx.h>], [Db *d = new Db(NULL, 0);],
	djm_cv_lib_db3_cxx_Db=yes, djm_cv_lib_db3_cxx_Db=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE])

if test $djm_cv_lib_db3_cxx_Db = yes; then
	LIBS="$LIBS -ldb3 -ldb3_cxx"
else

dnl Berkeley DB 4.0.x installed as libdb4 (as on FreeBSD).
AC_CACHE_CHECK([for Db in -ldb4_cxx], djm_cv_lib_db4_cxx_Db,
[AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS -ldb4 -ldb4_cxx"
AC_TRY_LINK([#include <db_cxx.h>], [Db *d = new Db(NULL, 0);],
	djm_cv_lib_db4_cxx_Db=yes, djm_cv_lib_db4_cxx_Db=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE])

if test $djm_cv_lib_db4_cxx_Db = yes; then
	LIBS="$LIBS -ldb4 -ldb4_cxx"
else

dnl Berkeley DB 4.1.x installed as libdb41 (as on FreeBSD).
AC_CACHE_CHECK([for Db in -ldb41_cxx], djm_cv_lib_db41_cxx_Db,
[AC_LANG_SAVE
AC_LANG_CPLUSPLUS
djm_save_LIBS="$LIBS"
LIBS="$LIBS -ldb41 -ldb41_cxx"
AC_TRY_LINK([#include <db_cxx.h>], [Db *d = new Db(NULL, 0);],
	djm_cv_lib_db41_cxx_Db=yes, djm_cv_lib_db41_cxx_Db=no)
LIBS="$djm_save_LIBS"
AC_LANG_RESTORE])

if test $djm_cv_lib_db41_cxx_Db = yes; then
	LIBS="$LIBS -ldb41 -ldb41_cxx"
else
	AC_MSG_ERROR([Berkeley DB library 2.x-4.x configured with --enable-cxx is required])
fi
fi
fi
fi
fi
fi])

DJM_LIB_DB_CXX

AC_OUTPUT(Makefile dns-terror/Makefile modules/Makefile scripts/Makefile
          scripts/btree-dump scripts/convert-dom-db scripts/convert-ip-db
          scripts/expire-ip-db scripts/getdominfo scripts/rebuild-dom-db
          scripts/rebuild-ip-db scripts/reresolve scripts/make-report)