C----------------------------------------------------------------------
        subroutine ftgcfm(iunit,colnum,frow,felem,nelem,array,
     &          flgval,anynul,status)

C       read an array of double precision complex values from a specified 
C       column of the table.
C       Any undefined pixels will be have the corresponding value of FLGVAL
C       set equal to .true., and ANYNUL will be set equal to .true. if
C       any pixels are undefined.

C       iunit   i  fortran unit number
C       colnum  i  number of the column to read
C       frow    i  first row to read
C       felem   i  first element within the row to read
C       nelem   i  number of elements to read
C       array   dcmp  returned array of data values that was read from FITS file
C       flgval  l  set .true. if corresponding element undefined
C       anynul  l  set to .true. if any of the returned values are undefined
C       status  i  output error status
C
C       written by Wm Pence, HEASARC/GSFC, June 1991

        integer iunit,colnum,frow,felem,nelem,status
        logical flgval(*),anynul
        double precision array(*),dummy
        integer i
        integer felemx, nelemx

C       a complex value is interpreted as a pair of float values, thus 
C       need to multiply the first element and number of elements by 2

        felemx = (felem - 1) * 2 + 1
        nelemx = nelem * 2

        do 10 i=1,nelemx
                flgval(i)=.false.
10      continue

        call ftgcld(iunit,colnum,frow,felemx,nelemx,1,2,dummy,
     &      array,flgval,anynul,status)
        end