Funcedilhaões e Variáveis Definidas para Montagem de Gráficos
=============================================================

 -- Funcedilhaão: contour_plot (EXPR, X_RANGE, Y_RANGE, OPCEDILHAÕES, ...)

     Monta gráficos de contorno (curvas de nível) de EXPR sobre a região X_RANGE por Y_RANGE. Quaisquer argumentos adicionals são tratados da mesma forma que em plot3d.

     contour_plot somente trabalha quando o formato do gráfico for gnuplot ou gnuplot_pipes.

     Veja também implicit_plot.

     Exemplos:

          (%i1) contour_plot (x^2 + y^2, [x, -4, 4], [y, -4, 4]);
          (%o1)
          (%i2) contour_plot (sin(y) * cos(x)^2, [x, -4, 4], [y, -4, 4]);
          (%o2)
          (%i3) F(x, y) := x^3 + y^2;
                                             3    2
          (%o3)                  F(x, y) := x  + y
          (%i4) contour_plot (F, [u, -4, 4], [v, -4, 4]);
          (%o4)
          (%i5) contour_plot (F, [u, -4, 4], [v, -4, 4], [gnuplot_preamble, "set size ratio -1"]);
          (%o5)
          (%i6) set_plot_option ([gnuplot_preamble, "set cntrparam levels 12"])$

          (%i7) contour_plot (F, [u, -4, 4], [v, -4, 4]);

 -- Variável: in_netmath
     Valor padrão: false

     Quando in_netmath é true, plot3d imprime uma saída OpenMath para o console se plot_format é openmath; caso contrário in_netmath (mesmo se true) não tem efeito. in_netmath não tem efeito sobre plot2d.

 -- Funcedilhaão: plot2d (EXPR, X_RANGE, ..., OPCEDILHAÕES, ...)
 -- Funcedilhaão: plot2d ([EXPR_1, ..., EXPR_N], ..., OPCEDILHAÕES, ...)
 -- Funcedilhaão: plot2d ([EXPR_1, ..., EXPR_N], X_RANGE,..., OPCEDILHAÕES, ...)

     onde EXPR, EXPR_1, ..., EXPR_N pode ser uma entre expressões, ou funcedilhaões do Lisp ou do Maxima ou operadores, ou uma lista com qualquer das formas: [discrete, [X1, ..., XN], [Y1, ..., YN]], [discrete, [[X1, Y1], ..., [XN, ..., YN]] ou [parametric, X_EXPR, Y_EXPR, T_RANGE].

     Mostra um gráfico de uma ou mais expressões como uma funcedilhaão de uma variável.

     plot2d monta o gráfico da expressão EXPR ou muitas expressões [NAME_1, ..., NAME_N]. As expressões que não forem paramétricas ou discretas podem todas depender somente de uma variável VAR e isso torna obrigatório o uso de X_RANGE para nome daquela variável e fornece seus valores de máximo e de mínimo, usando a sintaxe: [VARIABLE, MIN, MAX]. O gráfico irá mostrar o eixo horizontal associado aos valores de MIN e de MAX.

     Uma expressão a ser montado o gráfico pode também ser fornecida na forma discreta ou na forma paramétrica. A saber, como uma lista iniciando-se com a palavra ``discrete'' ou a palavra ``parametric''. A palavra chave DISCRETE deve ser seguida por duas listas de valores, ambas com o mesmo comprimento, que são as coodenadas horizontais e as coordenadas verticais de um conjunto de pontos; alternativamente, as coordenadas de cada ponto pode ser colocada dentro de uma lista com dois valores, e todas as coordenadas dos pontos podem estar dentro de outra lista. A palavra chave PARAMETRIC deve ser seguida por douas expressões X_EXPR e Y_EXPR, e um intervalo da forma [PARAM, MIN, MAX]. As duas expressões devem depender somente do parâmetro PARAM, e o gráfico irá mostrar o caminho percorrido pelo ponto com coordenadas (X_EXPR, Y_EXPR) com PARAM variando de MIN a MAX.

     O intervalo do eixo vertical não é obrigatório. É somente mais uma das opcedilhaões para o comando, com a sintaxe: [y, MIN,
     MAX]. Se aquela opcedilhaão for usada, o gráfico irá mostrar aquele intervalo completo, mesmo se a expressão não ocupe todo aquele intervalo. De outra forma, se um intervalo vertical não for especificado através de set_plot_option, as extremidade do eixo vertical serão encontrada automaticamente.

     Todas as outras opcedilhaões podem também serem listas, iniciando-se com o nome da opcedilhaão. A opcedilhaão XLABEL pode ser usada para fornecer um ótulo para o eixo horizontal; se aquela opcedilhaão não for usada, o eixo horizontal irá ser rotulado com o nome da variável especificada em X_RANGE, ou com a expressão X_EXPR no caso de apenas uma expressão paramétrica, ou isso irá ser deichado em branco de outra forma.

     Um rótulo para o eixo vertical pode ser fornecido com a opcedilhaão YLABEL. Se existir somente uma expressão a ser montado o gráfico e a opcedilhaão YLABEL não tiver sido usada, o eixo vertical irá ser rotulado com aquela expressão, a menos que ela seja muito larga, ou com a expressão Y_EXPR se a expressão for paramétrica, ou com o texto ``discrete data'' se a expressão for discreta.

     As opcedilhaões [logx] e [logy] não precisam de quaisquer parâmetros. Elas irão tornar os eixos horizontal e vertical sejam escritos em escala logarítmica.

     Se houverem muitas expressões para serem montados os gráficos respectivos, uma legenda irá ser escrita para identificar cada uma das expressões. Os rótulos que podem ser usados naquela legenda podem ser fornecidos com a opcedilhaão LEGEND. Se a opcedilhaão LEGEND não for usada, Maxima irá criar rótulos a partir das expressões.

     Por padrão, as expressões terão seus gráficos montados como um conjunto de segmentos de reta saltando pontos adjacentes dentro de um conjunt de pontos que é um dos fornecidos entre a forma DISCRETE, ou calculado automaticamente a partir da expressão fornecida, usando um algorítmo que automaticamente adapta os passos entre os pontos usando como uma estimativa inicial do total número de pontos o conjunto de valores com a opcedilhaão NTICKS. A opcedilhaão STYLE pode ser usada para fazer uma das expressões serem representadas como um conjunto de pontos isolados, ou como pontos e segmentos de reta.

     Existem muitas opcedilhaões globais armazenadas na lsita PLOT_OPTIONS que pode ser modificada com a funcedilhaão set_plot_option; qualque daquelas opcedilhaões globais pode ser sobrescrita com opcedilhaões fornecidas no comando PLOT2D.

     Uma funcedilhaão a ter seu gráfico montado pode ser especificada como o nome de uma funcedilhaão do Maxima ou do Lisp ou um operador, uma expressão lambda do Maxima, ou uma expressão geral do Maxima.  Se especificado como um nome ou uma expressão lambda, a funcedilhaão deve ser uma funcedilhaão de um argumento.

     Exemplos:

     Gráficos de funcedilhaões comuns.

          (%i1) plot2d (sin(x), [x, -5, 5])$

          (%i2) plot2d (sec(x), [x, -2, 2], [y, -20, 20], [nticks, 200])$

     Montando gráfico de funcedilhaões pelo nome.

          (%i3) F(x) := x^2 $

          (%i4) :lisp (defun |$g| (x) (m* x x x))

          $g
          (%i5) H(x) := if x < 0 then x^4 - 1 else 1 - x^5 $

          (%i6) plot2d (F, [u, -1, 1])$

          (%i7) plot2d ([F, G, H], [u, -1, 1])$

     Podemos montar o gráfico de um círculo usando um gráfico paramétrico com um parâmetro T. Não é necessário fornecer um intervalo para intervalo horizontal, uma vez que o intervalo do parâmetro T detrmina o domínio. Todavia, uma vez que os comprimentos dos eixos horizontal e vertical do gráfico estão na proporcedilhaão de 4 para 3, usaremos a opcedilhaão XRANGE para obter a mesma escala em ambos os eixos:

          (%i8) plot2d ([parametric, cos(t), sin(t), [t,-%pi,%pi], [nticks,80]],
                     [x, -4/3, 4/3])$

     Se repetirmos aquele gráfico com somente 8 pontos e extendendo o intervalo do parâmetro para fornecer dois turnos, obteremos o gráfico de uma estrela:

          (%i9) plot2d ([parametric, cos(t), sin(t), [t, -%pi*2, %pi*2],
                  [nticks, 8]], [x, -2, 2], [y, -1.5, 1.5])$

     Combinacedilhaão de um gráfico comum de um polinômio cúbico com um gráfico paramétrico de um círculo:

          (%i10) plot2d ([x^3 + 2, [parametric, cos(t), sin(t), [t, -5, 5],
                  [nticks, 80]]], [x, -3, 3])$

     Exemplo de um gráfico logarítmico:

          (%i11) plot2d (exp(3*s), [s, -2, 2], [logy])$

     Para mostrar alguns exemplos de gráficos discretos, iniciaremos por inserir as coordenadas de 5 pontos, por dois diferentes cominhos que podem ser usados:

          (%i12) xx:[10, 20, 30, 40, 50]$
          (%i13) yy:[.6, .9, 1.1, 1.3, 1.4]$
          (%i14) xy:[[10,.6], [20,.9], [30,1.1], [40,1.3], [50,1.4]]$

     Para montar o gráfico daqueles pontos, unidos com segmentos de reta, usamos:

          (%i15) plot2d([discrete,xx,yy])$

     Iremos agora mostrar o gráfico com somente pontoss, e ilustrando o uso do segundo caminho de fornecer as coordenadas dos pontos:

          (%i16) plot2d([discrete, xy], [style, points])$

     O gráfico de pontos pode ser mostrado juntamente com um gráfico da funcedilhaão teorética/doutrinária/estética que prevê as coordenads dos pontos:

          (%i17) plot2d([[discrete,xy], 2*%pi*sqrt(l/980)], [l,0,50],
                  [style, [points,3,5], [lines,1,3]], [legend,"experiment","theory"],
                  [xlabel,"pendulum's length (cm)"], [ylabel,"period (s)"])$

     Veja também plot_options, que descreve opcedilhaões de montagem de gráfico e tem mais exemplos.

 -- Funcedilhaão: xgraph_curves (LIST)
     transforma em gráfico a lista de `grupos de pontos' dados em lista usando xgraph.  Se o programa xgraph não estiver instalado, esse comando irá falhar.

     Um conjunto de pontos pode ser da forma

          [x0, y0, x1, y1, x2, y2, ...]

     ou

          [[x0, y0], [x1, y1], ...]

     Um conjunto de pontos pode também conter símbolos que fornecem rótulos ou outra informacedilhaão.

          xgraph_curves ([pt_set1, pt_set2, pt_set3]);

     transforma em gráfico os três conjuntos de pontos como três curvas.

          pt_set: append (["NoLines: True", "LargePixels: true"],
                                    [x0, y0, x1, y1, ...]);

     fizemos com que os grupos de pontos (e os próprios subseqüêntes), não possuam linhas entre si, e usassem pixels grandes. Veja a página de manual sobre o xgraph para especificar mais opcedilhaões.

          pt_set: append ([concat ("\"", "x^2+y")], [x0, y0, x1, y1, ...]);

     fizemos aí aparecer um "rótulo" de "x^2+y" para esse grupo de pontos em particular.  As aspas, ", no início é que dizem ao xgraph isso é um rótulo.

          pt_set: append ([concat ("TitleText: Dados da Amostra")], [x0, ...])$

     fizemos o título principal do gráfico ser "Dados da Amostra" ao invés de "Maxima Plot".

     Para fazer um gráfico em barras com largura de 0.2 unidades, e para montar o gráfico com duas possibilidades diferentes dos tais gráficos em barras:

          (%i1) xgraph_curves ([append (["BarGraph: true", "NoLines: true",
                "BarWidth: .2"], create_list ([i - .2, i^2], i, 1, 3)),
                append (["BarGraph: true", "NoLines: true", "BarWidth: .2"],
                create_list ([i + .2, .7*i^2], i, 1, 3))]);

     Um arquivo temporário xgraph-out é usado.

 -- Variável de sistema: plot_options
     Elementos dessa lista estabelecem as opcedilhaões padrão para a montagem do gráfico. Se uma opcedilhaão está presente em uma chamada a plot2d ou plot3d, esse valor tem precedência sobre a opcedilhaão padrão. De outra forma, o valor em plot_options é usado. Opcedilhaões padrão são atribuídas por set_plot_option.

     Cada elemento de plot_options é uma lista de dois ou mais ítens. O primeiro item é o nome de uma opcedilhaão, e os restantes compreendem o valor ou valores atribuídos à opcedilhaão. Em alguns casos, o valor atribuído é uma lista, que pode compreender muitos ítens.

     As opcedilhaões de montagem de gráfico que são reconhecidas por plot2d e plot3d são as seguintes:

       * Opcedilhaão: plot_format

          Determina qual interface gráfica é usada por plot2d e por plot3d.

            * Valor: gnuplot padrão para windows

               Gnuplot é o mais avancedilhaado pacote de montagem de gráficos entre os pacotes disponíveis no Maxima. Esse valor requer uma instalacedilhaão externa do gnuplot.

            * Valor: gnuplot_pipes padrão nas plantaformas não windows

               Similar ao formato gnuplot exceto que a comunicacedilhaão com o gnuplot é realizada através de um pipe. Esse valor pode ser usado para montar um gráfico na tela, para redirecionar a saída do gráfico para um arquivos é melhor usar o formato gnuplot.

            * Valor: mgnuplot

               Mgnuplot é um ambiente montado em volta do gnuplot baseado no Tk.  Esse ambiente está incluído na distribuícedilhaão do Maxima.  Mgnuplot oferece uma GUI rudimentar para o gnuplot, mas tem menos recursos em geral que a interface plana do gnuplot.  Mgnuplot requer uma instalacedilhaão externa do gnuplot e Tcl/Tk.

            * Valor: openmath

               Openmath é um programa gráfico escrito em Tcl/Tk. Este formato é fornecido pelo pacote Xmaxima, que é distribuído junto com Maxima; com o objetivo de usar esse formato você pode instalar o pacote Xmaxima, e o Openmath irá trabalhar não somente a partir do Xmaxima em si mesmo, mas também a apartir da linha de comando e outras GUI's para o Maxima.

       * Opcedilhaão: run_viewer

          Controla se o visualizador apropriado para o formato da montagem do gráfico pode ou não ser executado.

            * Valor padrão: true

               Executa o programa visualizador.

            * Valor: false

               Não executa o programa visualizador.

       * Opcedilhaão: y

          O intervalo vertical do gráfico.

          Exemplo:

               [y, - 3, 3]

          Especifica intervalo vertical para [-3, 3].

       * Opcedilhaão: plot_realpart

          Quando plot_realpart for true, a parte real de um valor complexo X é mostrada; isso é equivalente a mostrar realpart(X) em lugar de X. De outra forma, somente valores com a parte imaginária igual a 0 são mostrados na tela, e valores complexos são ignorados.

          Exemplo:

               plot2d (log(x), [x, -5, 5], [plot_realpart, false]);
               plot2d (log(x), [x, -5, 5], [plot_realpart, true]);

          O valor padrão é false.

       * Opcedilhaão: nticks

          Em plot2d, essa opcedilhaão é fornece o número inicial de pontos usado pela rotina adaptativa de montagem de gráficos para funcedilhaões de montagem de gráfico. Ess número inicial de pontos é também o número de pontos que isrá ser mostrado em um gráfico paramétrico.

          Exemplo:

               [nticks, 20]

          O padrão para nticks é 10.

       * Opcedilhaão: adapt_depth

          O número maximo de quebras usada pela rotina adaptativa de montagem do gráfico.

          Exemplo:

               [adapt_depth, 5]

          O padrão para adapt_depth é 10.

       * Opcedilhaão: xlabel

          O rótulo para o eixo horizontal em um gráfico bidimensional.

          Exemplo:

               [xlabel, "Time in seconds"]

       * Opcedilhaão: ylabel

          O rótulo do eixo vertical em gráficos bidimensionais.

          Exemplo:

               [ylabel, "Temperatura"]

       * Opcedilhaão: logx

          Essa opcedilhaão faz com que o eixo horizontal de um gráfico bidimensional seja desenhado em proporcedilhaão logarítmica. Essa opcedilhaão não precisa de quaisquer parâmetros adicionais.

       * Opcedilhaão: logy

          Essa opcedilhaão faz com que o eixo vertical de um gráfico bidimensional seja desenhado em proporcedilhaão logarítmica. Essa opcedilhaão não precisa de quaisquer parâmetros adicionais.

       * Opcedilhaão: legend

          Os rótulos para várias expressões em um gráfico bidimensional com muitas expressões. Se houverem mais expressões que o número de rótulos fornecidos, eles irão ser repetidos. Por padrão, os nomes das expressões ou funcedilhaõe irão ser usados, ou as palavras discrete1, discrete2, ..., para conjuntos discretos de pontos.

          Exemplo:

               [legend, "Conj 1", "Conj 2", "Conj 3"]

       * Opcedilhaão: style

          Os estilos que irão ser usados para várias funcedilhaões ou conjuntos de dados em um gráfico bidimensional. A palavra STYLE deve ser seguida por um ou mais estilos. Se houverem mais funcedilhaões e conjuntos de pontos que estilos fornecidos, os estilos irão ser repetidos. Cada estilo pode ser um entre os seguintes LINES para segmentos de reta, POINTS para pontos isolados, LINESPOINTS para segmentos e pontos, ou DOTS para pequenos pontos isolados. Gnuplot aceita também o estilo IMPULSES.

          Cada um dos estilos pode também ser fechado dentro de uma lista com alguns parâmetros adicionais. LINES aceita um ou dois números: a largura da linha e um inteiro que identifica uma cor. POINTS aceita um ou dois parâmetros; o primeiro parâmetro é o raio dos pontos e o segundo parâmetro é um inteiro que para o Gnuplot seleciona diferentes ajustes e cores para os ponots e em Openmath modifica a cor usada para os pontos. LINESDOTS aceita até quatro parâmetros; os primerios dois possuem o mesmo significado que em LINES e os últimos dois possuem o mesmo significado que em POINTS.

          Exemplo:

               [style,[lines,2,3],[points,1,4]]

          No Gnuplot, esse exemplo irá montar o gráfico da primeira (e terceira, quinta, etc) expressão com segmentos de retas azuis de largura 2, ea segunda (e quarta, sexta, etc) expressão com quadrados verdes de tamanho 1. No Openmath, a primeira expressão irá ser mostrada com segmentos da cor magenta de largura 2, e o segundo com pontos alaranjados de raio 1; note que openmath_color(3) openmath_color(4) retornam ``magenta'' e ``orange'' (alaranjado).

          O padrão para a opcedilhaão de estilo é LINES com largura 1, e diferentes cores.

       * Opcedilhaão: grid

          Escolhe o número de pontos da grade para usar nas direcedilhaões x e y para montagem de gráficos tridimensionais.

          Exemplo:

               [grid, 50, 50]

          Escolhe a grade para 50 por 50 pontos.  A grade padrão é 30 por 30.

       * Opcedilhaão: transform_xy

          Permite que transformacedilhaões sejam aplicadas à montagem de gráficos tridimensionais.

          Exemplo:

               [transform_xy, false]

          O valor padrão de transform_xy é false.  Se o valor padrão de transform_xy não é false, pode ser a saída de

               make_transform ([x, y, z], f1(x, y, z), f2(x, y, z), f3(x, y, z))$

          A transformacedilhaão polar_xy é previamente definida no Maxima.  Isso fornece a mesma transformacedilhaão que

               make_transform ([r, th, z], r*cos(th), r*sin(th), z)$

     Opcedilhaões do Gnuplot:

     Existem muitas opcedilhaões de montagem de gráfico específicas para gnuplot.  Algumas dessas opcedilhaões são naturais do gnuplot, especificados como seqüências de caracteres. Consulte a documentacedilhaão do gnuplot para mais detalhes.

       * Opcedilhaão: gnuplot_term

          Escolhe a saída para o tipo terminal para o gnuplot.

            * Valor padrão: default

               A saída do Gnuplot é mostrada em uma janela gráfica separada.

            * Valor: dumb

               A sída do Gnuplot é mostrada no console do Maxima por meio de uma "concepcedilhaão artística em ASCII" aproximada para gráficos.

            * Valor: ps

               Gnuplot gera comandos na linguagem PostScript de descricedilhaão de página. Se a opcedilhaão gnuplot_out_file for escolhida para NOMEARQUIVO, gnuplot escreve os comandos PostScript em NOMEARQUIVO. De outra forma, Esse arquivo é salvo com o nome maxplot.ps.

            * Valor: qualquer outra especificacedilhaão válida do terminal term do gnuplot

               Gnuplot pode gerar saídas em muitos outros formatos gráficos tais como png, jpeg, svg etc.  Paa criar gráficos em todos esses formatos a opcedilhaão gnuplot_term pode ser escolhida para qualquer terminalsuportado pelo gnuplot (símbolo) ou mesmo especificacedilhaão completa de terminal do gnuplot com quaisquer opcedilhaões (seqüência de caracteres). Por exemplo [gnuplot_term,png] cria saídas no formato PNG (Portable +Network Graphics) enquanto [gnuplot_term,"png size 1000,1000"] cria PNG de tamanho 1000x1000 pixels. Se a opcedilhaão gnuplot_out_file for escolhida para NOMEARQUIVO, gnuplot escreve a saída para NOMEARQUIVO. De outra forma, esse arquivo é gravado com o nome de maxplot.TERM, onde TERM é o nome do terminal do gnuplot .

       * Opcedilhaão: gnuplot_out_file

          Escreve a saída do gnuplot para um arquivo.

            * Valor padrão: false

               Nenhum arquivo de saída especificado.

            * Valor: NOMEARQUIVO

               Exemplo: [gnuplot_out_file, "meugrafico.ps"] Esse exemplo envia a saída PostScript para o arquivo meugrafico.ps quando usada conjuntamente com o terminal PostScript do gnuplot.

       * Opcedilhaão: gnuplot_pm3d

          Controla o uso do modo PM3D, que tem recursos avancedilhaados em 3D.  PM3D está somente disponível no gnuplot em versões após a 3.7.  O valor padrão para gnuplot_pm3d é false.

          Exemplo:

               [gnuplot_pm3d, true]

       * Opcedilhaão: gnuplot_preamble

          Insere comandos antes que o gráfico seja desenhado.  Quaisquer comandos válidos para o gnuplot podem ser usados.  Multiplos comandos podem ser separados com um ponto e vírgula.  O exemplo mostrado produz uma escala numérica na montagem do gráfico.  O valor padrão para gnuplot_preamble é uma seqüência de caracteres vazia "".

          Exemplo:

               [gnuplot_preamble, "set log y"]

       * Opcedilhaão: gnuplot_curve_titles

          Controla os títulos dados na chave da montagem do gráfico.  O valor padrão é [default], que automaticamente escolhe o título de cada curva para a funcedilhaão cujo gráfico está sendo construído. Se não contiver [default], gnuplot_curve_titles pode conter uma lista de seqüências de caracteres, cada uma das quais é "title 'TITLE_STRING'". (Para disabilitar a chave de impressão de gráfico, adicione "set nokey" a gnuplot_preamble.)

          Exemplo:

               [gnuplot_curve_titles,
               ["title 'Minha primeira funcedilhaão'", "title 'Minha segunda funcedilhaão'"]]

       * Opcedilhaão: gnuplot_curve_styles

          Uma lista de seqüências de caracteres controlando a aparência das curvas, i.e., cor, largura, brilho, etc., para serem enviadas para o comando de montagem do gráfico do gnuplot.  O valor padrão é ["with lines 3", "with lines 1", "with lines 2", "with lines 5", "with lines 4", "with lines 6", "with lines 7"], que circula através de diferentes cores.  Veja a documentacedilhaão do gnuplot de plot para maiores informacedilhaões.

          Exemplo:

               [gnuplot_curve_styles, ["with lines 7", "with lines 2"]]

       * Opcedilhaão: gnuplot_default_term_command

          O comando gnuplot para escolher o tipo de terminal para o terminal padrão. O valor padrão é set term windows "Verdana" 15 em sistemas windows, e set term x11 font "Helvetica,16" em sistemas de janelas do X11.

          Exemplo:

               [gnuplot_default_term_command, "set term x11"]

       * Opcedilhaão: gnuplot_dumb_term_command

          O comando gnuplot para escolher o tipo de terminal para o terminal dumb.  O valor padrão é "set term dumb 79 22", que faz a saída texto com 79 caracteres por 22 caracteres.

          Exemplo:

               [gnuplot_dumb_term_command, "set term dumb 132 50"]

       * Opcedilhaão: gnuplot_ps_term_command

          O comando gnuplot para escolher o tipo de terminal para o terminal PostScript.  O valor padrão é "set size 1.5, 1.5;set term postscript eps enhanced color solid 24", que escolhe o tamanho para 1.5 vezes o padrão do gnuplot, e o tamanho da fonte para 24, além de outras coisas.  Veja a documentacedilhaão do gnuplot de set term postscript para mais informacedilhaão.

          Exemplo:

          Todos os números nos exemplos para a funcedilhaão PLOT2D nesse manual foram obtidos de arquivos Postscript que foram gerados após escolher gnuplot_ps_term_command como:

               [gnuplot_ps_term_command,
               "set size 1.3, 1.3; set term postscript eps color solid lw 2.5 30"]

     Exemplos:

       * Grava um gráfico de sin(x) para o arquivo sin.eps.

          (%i1) plot2d (sin(x), [x, 0, 2*%pi], [gnuplot_term, ps],
                                  [gnuplot_out_file, "sin.eps"])$

       * Usa a opcedilhaão do y para arrancar singularidades e a opcedilhaão gnuplot_preamble para colocar a chave na parte inferior do gráfico em lugar de no topo.

          (%i2) plot2d ([gamma(x), 1/gamma(x)], [x, -4.5, 5], [y, -10, 10],
                               [gnuplot_preamble, "set key bottom"])$

       * Usa um muito complicado gnuplot_preamble para produzir elegantes rótulos para o eixo x. (Note que a seqüência de caracteres gnuplot_preamble deve ser fornecida inteiramente sem qualquer quebra de linha.)

          (%i3) my_preamble: "set xzeroaxis; set xtics ('-2pi' -6.283, \
          '-3pi/2' -4.712, '-pi' -3.1415, '-pi/2' -1.5708, '0' 0, \
          'pi/2' 1.5708, 'pi' 3.1415,'3pi/2' 4.712, '2pi' 6.283)"$

          (%i4) plot2d([cos(x), sin(x), tan(x), cot(x)],
                 [x, -2*%pi, 2.1*%pi], [y, -2, 2],
                 [gnuplot_preamble, my_preamble]);

       * Usa um muito complicad gnuplot_preamble para produzir elegantes rótulos para o eixo x, e produzir saídas PostScript que aproveita as vantagens do formato de texto avancedilhaado disponível no gnuplot. (Note que a seqüência de caracteres gnuplot_preamble deve ser fornecida inteiramente sem qualquer quebra de linha.)

          (%i5) my_preamble: "set xzeroaxis; set xtics ('-2{/Symbol p}' \
          -6.283, '-3{/Symbol p}/2' -4.712, '-{/Symbol p}' -3.1415, \
          '-{/Symbol p}/2' -1.5708, '0' 0,'{/Symbol p}/2' 1.5708, \
          '{/Symbol p}' 3.1415,'3{/Symbol p}/2' 4.712, '2{/Symbol p}' \
          6.283)"$

          (%i6) plot2d ([cos(x), sin(x), tan(x)], [x, -2*%pi, 2*%pi],
              [y, -2, 2], [gnuplot_preamble, my_preamble],
              [gnuplot_term, ps], [gnuplot_out_file, "trig.eps"]);

       * Uma montagem de gráfico tridimensional usando o terminal gnuplot pm3d.

          (%i7) plot3d (atan (-x^2 + y^3/4), [x, -4, 4], [y, -4, 4],
                  [grid, 50, 50], [gnuplot_pm3d, true])$

       * Uma montagem de gráfico tridimensional sem a malha e com contornos projetados no plano inferior.

          (%i8) my_preamble: "set pm3d at s;unset surface;set contour;\
          set cntrparam levels 20;unset key"$
          (%i9) plot3d(atan(-x^2 + y^3/4), [x, -4, 4], [y, -4, 4],
              [grid, 50, 50], [gnuplot_pm3d, true],
              [gnuplot_preamble, my_preamble])$

       * Uma montagem de gráfico onde o eixo z é representado apenas por cores. (Note que a seqüência de caracteres gnuplot_preamble deve ser fornecida inteiramente sem qualquer quebra de linha.)

          (%i10) plot3d (cos (-x^2 + y^3/4), [x, -4, 4], [y, -4, 4],
              [gnuplot_preamble, "set view map; unset surface"],
              [gnuplot_pm3d, true], [grid, 150, 150])$

 -- Funcedilhaão: plot3d ([EXPR_1, EXPR_2, EXPR_3], X_RANGE, Y_RANGE, ..., OPCEDILHAÕES, ...)
 -- Funcedilhaão: plot3d (EXPR, X_RANGE, Y_RANGE, ..., OPCEDILHAÕES, ...)
 -- Funcedilhaão: plot3d (NAME, X_RANGE, Y_RANGE, ..., OPCEDILHAÕES, ...)
 -- Funcedilhaão: plot3d ([EXPR_1, EXPR_2, EXPR_3], X_RGE, Y_RGE)
 -- Funcedilhaão: plot3d ([NOME_1, NOME_2, NOME_3], X_RANGE, Y_RANGE, ..., OPCEDILHAÕES, ...)

     Mostra um gráfico de uma ou três expressões como funcedilhaões de duas variáveis.

          (%i1) plot3d (2^(-u^2 + v^2), [u, -3, 3], [v, -7, 7]);

     monta o gráfico de z = 2^(-u^2+v^2) com u e v variando no intervalo fechado [-3,3] e no intervalo fechado de [-2,2] respectivamente, e com U sobre o eixo x, e v sobre o eixo y.

     O mesmo gráfico pode ser visualizado usando openmath (se Xmaxima estiver instalado):

          (%i2)  plot3d (2^(-u^2 + v^2), [u, -3, 3], [v, -2, 2],
                         [plot_format, openmath]);

     nesse caso o mouse pode ser usado para rotacionar a visualizacedilhaão para olhar na superfície de diferentes ângulos.

     Um exemplo do terceiro modelo de argumento é

          (%i3) plot3d ([cos(x)*(3 + y*cos(x/2)), sin(x)*(3 + y*cos(x/2)),
             y*sin(x/2)], [x, -%pi, %pi], [y, -1, 1], ['grid, 50, 15]);

     que monta o gráfico da banda de Moebius, parametrizada por três expressões fornecidas como o primeiro argumento para plot3d.  O argumento adiconal porém opcional ['grid, 50, 15] fornece o número de retâgulos da grade na direcedilhaão x e na direcedilhaão y.

     Uma funcedilhaão a ter seu gráfico montado pode ser especificada como o nome de uma funcedilhaão Maxima ou como o nome de uma funcedilhaão Lisp ou como um operador, como uma expressão lambda do Maxima, ou como uma expressão geral do Maxima. Se especificada como um nome ou como expressão lambda, a funcedilhaão deve ser uma funcedilhaão de um argumento.

     Esse exemplo mostra uma montagem de gráfico da parte real de z^1/3.

          (%i4) plot3d (r^.33*cos(th/3), [r, 0, 1], [th, 0, 6*%pi],
                ['grid, 12, 80], ['transform_xy, polar_to_xy]);

     Outro exemplo é uma superfície de Klein:

          (%i5) expr_1: 5*cos(x)*(cos(x/2)*cos(y) + sin(x/2)*sin(2*y)
                + 3.0) - 10.0$
          (%i6) expr_2: -5*sin(x)*(cos(x/2)*cos(y) + sin(x/2)*sin(2*y)
                + 3.0)$
          (%i7) expr_3: 5*(-sin(x/2)*cos(y) + cos(x/2)*sin(2*y))$

          (%i8) plot3d ([expr_1, expr_2, expr_3], [x, -%pi, %pi],
                [y, -%pi, %pi], ['grid, 40, 40]);

     e um toro

          (%i9) expr_1: cos(y)*(10.0+6*cos(x))$
          (%i10) expr_2: sin(y)*(10.0+6*cos(x))$
          (%i11) expr_3: -6*sin(x)$
          (%i12) plot3d ([expr_1, expr_2, expr_3], [x, 0, 2*%pi],       [y, 0, 2*%pi], ['grid, 40, 40]);

     Algumas vezes isso é necessário para definir uma funcedilhaão para montar o graico da expressão. Todos os argumentos para plot3d são avaliados antes de serem passados para plot3d. Tentar fazer um expressão que faz apenas o que é preciso pode ser difícil e pode ser mais fácil fazer uma funcedilhaão.

          (%i13) M: matrix([1, 2, 3, 4], [1, 2, 3, 2], [1, 2, 3, 4],
                 [1, 2, 3, 3])$
          (%i14) f(x, y) := float (M [?round(x), ?round(y)])$
          (%i15) plot3d (f, [x, 1, 4], [y, 1, 4], ['grid, 4, 4])$

     Veja plot_options para mais exemplos.

 -- Funcedilhaão: make_transform (VARS, FX, FY, FZ)
     Retorna uma funcedilhaão adequada para a funcedilhaão transformacedilhaão em plot3d.  Use com a opcedilhaão de montagem de gráfico transform_xy.

          make_transform ([r, th, z], r*cos(th), r*sin(th), z)$

     é uma transformacedilhaão para coordenadas polares.

 -- Funcedilhaão: set_plot_option (OPCEDILHAÃO)
     Atribui uma das varáveis globais para impressão. OPCEDILHAÃO é especificada como uma lista de dois ou mais elementos, na qual o primeiro elemento é uma das palavras chave dentro da lista plot_options.

     set_plot_option avalia seu argumento e retorna a liasta completa plot_options (após modificar um de seus elementos).

     Veja também plot_options, plot2d, e plot3d.

     Exemplos:

     Modifica a malha (grid) e valores de x. Quando uma palavra chave em plot_options tem um valor atribuído, colocar um apóstrofo evita avaliacedilhaão.

          (%i1) set_plot_option ([grid, 30, 40]);
          (%o1) [[x, - 1.755559702014E+305, 1.755559702014E+305],
          [y, - 1.755559702014E+305, 1.755559702014E+305], [t, - 3, 3],
          [grid, 30, 40], [transform_xy, false], [run_viewer, true],
          [plot_format, gnuplot], [gnuplot_term, default],
          [gnuplot_out_file, false], [nticks, 10], [adapt_depth, 10],
          [gnuplot_pm3d, false], [gnuplot_preamble, ],
          [gnuplot_curve_titles, [default]],
          [gnuplot_curve_styles, [with lines 3, with lines 1,
          with lines 2, with lines 5, with lines 4, with lines 6,
          with lines 7]], [gnuplot_default_term_command, ],
          [gnuplot_dumb_term_command, set term dumb 79 22],
          [gnuplot_ps_term_command, set size 1.5, 1.5;set term postscript #
          eps enhanced color solid 24]]
          (%i2) x: 42;
          (%o2)                          42
          (%i3) set_plot_option (['x, -100, 100]);
          (%o3) [[x, - 100.0, 100.0], [y, - 1.755559702014E+305,
          1.755559702014E+305], [t, - 3, 3], [grid, 30, 40],
          [transform_xy, false], [run_viewer, true],
          [plot_format, gnuplot], [gnuplot_term, default],
          [gnuplot_out_file, false], [nticks, 10], [adapt_depth, 10],
          [gnuplot_pm3d, false], [gnuplot_preamble, ],
          [gnuplot_curve_titles, [default]],
          [gnuplot_curve_styles, [with lines 3, with lines 1,
          with lines 2, with lines 5, with lines 4, with lines 6,
          with lines 7]], [gnuplot_default_term_command, ],
          [gnuplot_dumb_term_command, set term dumb 79 22],
          [gnuplot_ps_term_command, set size 1.5, 1.5;set term postscript #
          eps enhanced color solid 24]]

Funcedilhaões para trabalhar com o formato gnuplot_pipes
--------------------------------------------------------

 -- Funcedilhaão: gnuplot_start ()

     Abre o pipe para o gnuplot usado para montar um gráfico com o formato gnuplot_pipes. Não é necessário abrir manualmente o pipe antes de montar o gráfico.

 -- Funcedilhaão: gnuplot_close ()

     Fecha o pipe para o gnuplot que está sendo usado com o formato gnuplot_pipes.

 -- Funcedilhaão: gnuplot_restart ()

     Fecha o pipe para o gnuplot que é usado com o formato gnuplot_pipes e abre um novo pipe.

 -- Funcedilhaão: gnuplot_replot ()
 -- Funcedilhaão: gnuplot_replot (S)

     Atualiza a janela gráfica do gnuplot. Se gnuplot_replot for chamado com um comando gnuplot em uma seqüência de caracteres S, então s é enviado para o gnuplot antes de atualizar a janela.

 -- Funcedilhaão: gnuplot_reset ()

     Restaura o estado inicial padrão do gnuplot usado com o formato gnuplot_pipes. Para atualizar a janela do gnuplot chama gnuplot_replot após gnuplot_reset.