dnl 
dnl $Id: configure.in,v 1.1.1.2.2.11 2002/02/23 01:57:02 nevil Exp $
dnl 

AC_INIT(src/snmplib/asn1.c)
AC_CONFIG_HEADER(ntm_conf.h:ntm_conf.hin)

AC_CONFIG_AUX_DIR(etc)
AC_CANONICAL_SYSTEM

case "$target" in
*linux*)
	OS=LINUX
	;;
*sunos*)
	OS=SUNOS
	;;
*irix*)
	OS=IRIX
	;;
*solaris*)
	OS=SOLARIS
	MOTIF_LIB=-L/usr/dt/lib
	MOTIF_INC=-I/usr/dt/include
	;;
*freebsd*)
	OS=FREEBSD
	;;
*netbsd*)
	OS=NETBSD
	;;
*dec-os*)
	OS=ALPHA
	;;
*cygwin32*)
	OS=CYGWIN32
	;;
*)
	OS=UNIX
	;;
esac

echo "----- target OS=$OS"

dnl Preprocessor Symbols
dnl
AC_DEFINE(NEW_ATR)
AC_DEFINE(TCP_ATR)
AC_DEFINE(V6, 0) 
   # To build v6-capable programs
   #    edit configure to set V6 to 1         <- <-
GFLAG=
   # To build object files with symbol info for debugger
   #    edit configure to define  GFLAG=-g    <- <-

dnl Program Checks
dnl
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL
AC_C_BIGENDIAN
AC_CHECK_SIZEOF(long)
AC_CHECK_SIZEOF(long long)

dnl Library Snoops
dnl
AC_CHECK_LIB(m, floor)
AC_CHECK_LIB(socket, socket)
AC_CHECK_LIB(nsl, inet_ntoa)
AC_CHECK_LIB(resolv, res_query)

if test "$OS" = CYGWIN32; then  # Libraries may be in src/meter
   AC_CHECK_LIB(pcap, pcap_major_version,
      [  PCAP="-lpcap -L."
         METER_TARGET='$(PCAP_PROGS) $(NO_PCAP_PROGS) if_list look_tst'],
      [  echo ">>>>> libpcap.a not found: won't be able to build NeTraMet"
         METER_TARGET='$(NO_PCAP_PROGS)'],
      -Lsrc/meter
      )
else
   AC_CHECK_LIB(pcap, pcap_major_version,
      [  PCAP=-lpcap
         METER_TARGET='$(PCAP_PROGS) $(NO_PCAP_PROGS)'],
      [  echo ">>>>> libpcap not found: won't be able to build NeTraMet"
         METER_TARGET='$(NO_PCAP_PROGS)']
      )
fi

AC_PATH_XTRA
if test "$no_x" = yes; then
   echo ">>>>> No X support: won't be able to build nifty"
   MGR_TARGET='$(NO_X_PROGS)'
fi

have_Xm=no
AC_CHECK_LIB(Xm, XmStringFree, have_Xm=yes, , $MOTIF_LIB)
if test "$have_Xm" = no; then
   CFLAGS="$CFLAGS $X_CFLAGS"  # check_lib doesn't seem to work for linux!
   AC_TRY_COMPILE(
      [#include <Xm/XmStrDefs.h>],
      ,
      have_Xm=yes, )
   echo "checking for Xm/XmStrDefs.h using X_CFLAGS... $have_Xm"
fi
if test "$have_Xm" = yes; then
   MGR_TARGET='$(NO_X_PROGS) $(X_PROGS)'
else
   echo ">>>>> Motif not found: won't be able to build nifty"
   MGR_TARGET='$(NO_X_PROGS)'
fi

AC_HEADER_STDC
AC_HEADER_TIME
AC_CHECK_HEADERS(sys/types.h sys/select.h getopt.h memory.h malloc.h string.h stropts.h)
AC_CHECK_FUNCS(memmove)

AC_DEFINE(unix)  # Add unix to DEFS
# AC_DEFINE(__unix__)  # This confuses the confdefs.h substitution !!!

dnl Build Makefiles
dnl
AC_SUBST(OS)
AC_SUBST(GFLAG)
AC_SUBST(PCAP)
AC_SUBST(METER_TARGET)
AC_SUBST(MOTIF_LIB)
AC_SUBST(MOTIF_INC)
AC_SUBST(MGR_TARGET)
AC_SUBST(DEFAULT_MIB)
AC_OUTPUT(Makefile src/snmplib/Makefile src/apps/Makefile src/bgp/Makefile src/srl/Makefile src/manager/Makefile src/meter/Makefile examples/Makefile mib/Makefile)

dnl This is for GNU Emacs...
dnl ========================
dnl Local Variables:
dnl compile-command: "autoconf"
dnl End: