AC_INIT(link-monitor-applet, 2.1, jylefort@brutele.be)
AC_CONFIG_SRCDIR(src/lm-main.c)

AC_PREREQ(2.59)

# by default, install in the same prefix as GNOME
AC_PREFIX_PROGRAM(gnome-open)

### command line arguments

LM_ARG_ENABLE(ipv6, [disable IPv6 support])
LM_ARG_ENABLE(geoip, [do not use GeoIP])

LM_ARG_COMPILE_WARNINGS
LM_ARG_DEBUG

### initialization

# needed by AC_REENTRANT_RESOLVER
AC_CANONICAL_TARGET

AM_INIT_AUTOMAKE(foreign)
AM_MAINTAINER_MODE
AM_CONFIG_HEADER(config.h)

### i18n

GETTEXT_PACKAGE=AC_PACKAGE_NAME
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", [Define to the gettext package name])
AC_SUBST(GETTEXT_PACKAGE)

ALL_LINGUAS="fr"
AM_GLIB_GNU_GETTEXT

AC_PROG_INTLTOOL

### system features

AC_PROG_CC
AC_SYS_LARGEFILE

# check for ANSI C headers
AC_HEADER_STDC
if test $ac_cv_header_stdc != yes; then
	AC_MSG_ERROR([ANSI C headers not present])
fi

AC_REENTRANT_RESOLVER

### mandatory libraries and programs

AM_PATH_GTK_2_0(2.8.0,, [AC_MSG_ERROR([unable to find the GTK+ library])])

PKG_CHECK_MODULES(GNOME, [gthread-2.0 libgnomeui-2.0 libpanelapplet-2.0 libglade-2.0 eel-2.0],, [AC_MSG_ERROR([unable to find the GNOME libraries])])
AM_GCONF_SOURCE_2

AM_PATH_GNOME_PREFIX

AC_PATH_PROG(GCONFTOOL, gconftool-2)
if test -z "$GCONFTOOL"; then
	AC_MSG_ERROR([unable to find the gconftool-2 program])
fi

### optional libraries and programs

# not needed by end-users, as generated files are distributed
AC_PATH_PROG(AML, aml)
AC_PATH_PROG(GOB2, gob2)

if LM_FEATURE_ENABLED(geoip); then
	AM_PATH_GEOIP(, [LM_FEATURE_DISABLE(geoip, [GeoIP not found])])
	if LM_FEATURE_ENABLED(geoip); then
		AC_GDK_PIXBUF_LOADER([art/flags/fr.svg], [image/svg+xml],, [AC_MSG_WARN([GTK+ cannot load image/svg+xml images, country flags will not be displayed])])
	fi
fi

### Automake conditionals

AM_CONDITIONAL(WITH_GEOIP, [LM_FEATURE_ENABLED(geoip)])

### config.h definitions

LM_FEATURES_DEFINE([ipv6, geoip])

### output

AC_CONFIG_FILES(Makefile
		art/Makefile
		data/Makefile
		help/Makefile
		help/C/Makefile
		m4/Makefile
		po/Makefile.in
		src/Makefile
		ui/Makefile)
AC_OUTPUT

### report

cat <<EOF

$PACKAGE $VERSION is ready to be built.
The following settings will be used:

Installation prefixes
LM_REPORT_ARGS([prefix, exec-prefix])
Installation directories
LM_REPORT_ARGS([libexecdir, datadir, sysconfdir, libdir])
Features
LM_REPORT_FEATURES([ipv6, geoip])
EOF

if test -z "$gnome_prefix"; then
	AC_MSG_WARN([$PACKAGE_NAME must be installed in the same prefix as GNOME, but the GNOME prefix could not be found. $PACKAGE_NAME might be inoperable.])
	echo "" >&2
else
	if test "x$prefix" != "x$gnome_prefix"; then
		AC_MSG_WARN([the $PACKAGE_NAME prefix ($prefix) is different from the GNOME prefix ($gnome_prefix). $PACKAGE_NAME will be inoperable. Unless you know what you are doing, please run "./configure --prefix=$gnome_prefix".])
		echo "" >&2
	fi
fi

cat <<EOF
Type "make" to build $PACKAGE_NAME $VERSION.
EOF