dnl Process this file with autoconf to produce a configure script.
AC_INIT(yafic.c)
AM_INIT_AUTOMAKE(yafic, 1.2.2)
AM_CONFIG_HEADER(config.h)

dnl Checks for programs.
AC_PROG_CC

AC_ARG_ENABLE(crypto,
AC_HELP_STRING([--disable-crypto],[disable database signing/verification]),,
enable_crypto=yes)

if test "$enable_crypto" = "yes"; then
  AC_PATH_PROG(OPENSSL, openssl, notfound)
  if test "$OPENSSL" != "notfound"; then
    AC_DEFINE([YAFIC_CRYPTO], 1, [Define to 1 if using OpenSSL's libcrypto.])
    CRYPTO_PROGRAMS="yafic-sign"
    CRYPTO_MANS="yafic-sign.1"
  fi
fi
AC_SUBST(CRYPTO_PROGRAMS)
AC_SUBST(CRYPTO_MANS)

dnl Checks for libraries.
APS_SEARCH_BDB_185_HEADER
if test "$aps_cv_bdb_header" = "not found"; then
  AC_MSG_ERROR([cannot find Berkeley DB 1.xx header])
fi
YAFIC_DB_HEADER=$aps_cv_bdb_header
AC_SUBST(YAFIC_DB_HEADER)
APS_SEARCH_BDB_185_LIB
if test "$aps_cv_bdb_lib" = "no"; then
  AC_MSG_ERROR([cannot find Berkeley DB 1.xx library])
fi
if test "$enable_crypto" = "yes"; then
  if test "$OPENSSL" != "notfound"; then
    AC_SEARCH_LIBS([EVP_SignFinal], crypto)
  fi
fi

dnl Checks for header files.
AC_HEADER_DIRENT
AC_CHECK_HEADERS(libgen.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_BIGENDIAN
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T
AC_CHECK_TYPE([uint8_t],,
[AC_DEFINE([uint8_t], [unsigned char],
[Define to `unsigned char' if not defined.])])
AC_CHECK_TYPE([uint32_t],,
[AC_DEFINE([uint32_t], [unsigned int],
[Define to `unsigned int' if not defined.])])
AC_CHECK_TYPE([uint64_t],,
[AC_DEFINE([uint64_t], [unsigned long long],
[Define to `unsigned long long' if not defined.])])

dnl Figure out the size of relevant stat fields.
APS_CHECK_STAT_SIZEOF(st_mode, 4)
APS_CHECK_STAT_SIZEOF(st_ino, 4)
APS_CHECK_STAT_SIZEOF(st_nlink, 4)
APS_CHECK_STAT_SIZEOF(st_uid, 4)
APS_CHECK_STAT_SIZEOF(st_gid, 4)
APS_CHECK_STAT_SIZEOF(st_size, 4)
APS_CHECK_STAT_SIZEOF(st_atime, 4)
APS_CHECK_STAT_SIZEOF(st_mtime, 4)
APS_CHECK_STAT_SIZEOF(st_ctime, 4)

dnl Checks for library functions.
AC_FUNC_SETVBUF_REVERSED
AC_REPLACE_FUNCS(dirname strlcat strlcpy)
if test "$enable_crypto" = "yes"; then
  if test "$OPENSSL" != "notfound"; then
    AC_CHECK_FUNCS(EVP_MD_CTX_init EVP_MD_CTX_cleanup)
    APS_FUNC_EVP_DIGESTINIT_VOID
  fi
fi

AC_OUTPUT([Makefile yafic-db.h])