AC_PREREQ(2.53)
AC_INIT(src)
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE(battfink, 0.6.2) 

AM_MAINTAINER_MODE

AC_PROG_INTLTOOL([0.21])

dnl ********************************
dnl I bet I don't need half of these
dnl ********************************

AC_ISC_POSIX
AC_PROG_CXX
AC_PROG_CC
AC_PROG_CPP
AC_STDC_HEADERS
AC_PROG_YACC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET
AC_PATH_XTRA
AC_PATH_PROG(GCONFTOOL, gconftool-2)
AM_GCONF_SOURCE_2

GNOME_COMPILE_WARNINGS

PKG_CHECK_MODULES(BATTFINK, gtk+-2.0 libglade-2.0 gconf-2.0 libgnomeui-2.0)
AC_SUBST(BATTFINK_CFLAGS)
AC_SUBST(BATTFINK_LIBS)

ORBIT_IDL="`$PKG_CONFIG --variable=orbit_idl ORBit-2.0`"
AC_SUBST(ORBIT_IDL)

LIBBONOBO_IDL="`$PKG_CONFIG --variable=idldir libbonobo-2.0`"
AC_SUBST(LIBBONOBO_IDL)

BONOBO_ACTIVATION_IDL="`$PKG_CONFIG --variable=idldir bonobo-activation-2.0`"
AC_SUBST(BONOBO_ACTIVATION_IDL)

PLUGIN_LIBTOOL_FLAGS="-module -avoid-version"
AC_SUBST(PLUGIN_LIBTOOL_FLAGS)

AC_CHECK_LIB(popt, poptHelpOptions,, AC_MSG_ERROR([popt is required to build script.]))

dnl ***********************************************
dnl scrollkeeper checks - don't use these currently
dnl ***********************************************
dnl
dnl AC_PATH_PROG(SCROLLKEEPER_CONFIG, scrollkeeper-config,no)
dnl if test x$SCROLLKEEPER_CONFIG = xno; then
dnl   AC_MSG_ERROR(Couldn't find scrollkeeper-config. Please install the scrollkeeper package)
dnl fi


dnl ***********************************************
dnl dpms checks - X11/extensions/dpms.h
dnl ***********************************************

AC_DEFUN(AC_CHECK_X_HEADER, [
  ac_save_CPPFLAGS="$CPPFLAGS"
  if test \! -z "$includedir" ; then
    CPPFLAGS="$CPPFLAGS -I$includedir"
  fi
  CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  AC_CHECK_HEADER([$1],[$2],[$3],[$4])
  CPPFLAGS="$ac_save_CPPFLAGS"
])

AC_DEFUN(AC_CHECK_X_LIB, [
  ac_save_CPPFLAGS="$CPPFLAGS"
  ac_save_LDFLAGS="$LDFLAGS"
  if test \! -z "$includedir" ; then
    CPPFLAGS="$CPPFLAGS -I$includedir"
  fi
  # note: $X_CFLAGS includes $x_includes
  CPPFLAGS="$CPPFLAGS $X_CFLAGS"
  if test \! -z "$libdir" ; then
    LDFLAGS="$LDFLAGS -L$libdir"
  fi
  # note: $X_LIBS includes $x_libraries
  LDFLAGS="$LDFLAGS $X_LIBS $X_EXTRA_LIBS"
  AC_CHECK_LIB([$1], [$2], [$3], [$4], [$5])
  CPPFLAGS="$ac_save_CPPFLAGS"
  LDFLAGS="$ac_save_LDFLAGS"
])

enable_dpms=no

dnl Check for dpms.h
AC_CHECK_X_HEADER(X11/extensions/dpms.h, [enable_dpms=yes],, [#include <X11/Xlib.h>])

dnl If we found dpms.h, check for the libs
if test "$enable_dpms" = yes; then

  dnl first look in -lXext (this is where it is with XFree86 4.0)
  enable_dpms=no
  AC_CHECK_X_LIB(Xext, DPMSInfo, [enable_dpms=yes], [true], -lXext -lX11)

  dnl if that failed, look in -lXdpms (this is where it was in XFree86 3.x)
  if test "$enable_dpms" = no; then
    AC_CHECK_X_LIB(Xdpms, DPMSInfo, [enable_dpms=yes; XDPMS_LIBS="-lXdpms"], [true], -lXext -lX11)
  fi
fi

dnl Okay, we now are sure if we have dpms or not ;)

if test "$enable_dpms" = yes; then
  AC_DEFINE(HAVE_EXTENSION_DPMS, 1, [We have dpms enabled X server extension])
  AC_SUBST(HAVE_EXTENSION_DPMS)
fi

dnl *******************************
dnl apm checks - apm.h
dnl ******************************* 

enable_apm=no

dnl We can't seem to check the header, because it gives compiler
dnl warnings, so we check for the libs instead

AC_CHECK_LIB(apm, apm_read, [enable_apm=yes], [enable_apm=no])

if test "$enable_apm" = yes; then
  enable_apm=no
  AC_CHECK_HEADERS(apm.h, [enable_apm=yes])
  if test "$enable_apm" = yes; then
    AC_DEFINE(HAVE_APM, 1, [We have apm power saving library])
    AC_SUBST(HAVE_APM)
  fi
fi
AM_CONDITIONAL(HAVE_APM, test "$enable_apm" = yes)

dnl *******************************
dnl Internationalization
dnl ******************************* 

ALL_LINGUAS="az da de el es fr hi ja ms nl no pl pt pt_BR ru sr sr@Latn sv tr zh_CN zh_TW"
GETTEXT_PACKAGE=battfink-0.1
AC_SUBST(GETTEXT_PACKAGE)
AM_GLIB_GNU_GETTEXT

dnl **************************************************************
dnl AM_GLIB_GNU_GETTEXT above substs $DATADIRNAME
dnl this is the directory where the *.{mo,gmo} files are installed
dnl **************************************************************

battfinklocaledir='${prefix}/${DATADIRNAME}/locale'
AC_SUBST(battfinklocaledir)

AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE,"$GETTEXT_PACKAGE", [Finding gettext package])

AC_DEFINE_UNQUOTED(GNOME_ICONDIR, "${prefix}/share/pixmaps", [Determining icon location])

AC_SUBST(CFLAGS)
AC_SUBST(CPPFLAGS)
AC_SUBST(LDFLAGS)

AC_OUTPUT([
Makefile
battfink.spec
po/Makefile.in
src/Makefile
data/Makefile
help/Makefile
help/C/Makefile
])