-*- mode: autoconf -*-
AC_PREREQ(2.52)

dnl the gnome-python version number
m4_define(gnome_python_major_version, 1)
m4_define(gnome_python_minor_version, 4)
m4_define(gnome_python_micro_version, 4)
m4_define(gnome_python_version, gnome_python_major_version.gnome_python_minor_version.gnome_python_micro_version)

dnl required versions of other packages.
m4_define(glib_required_version, 1.2.10)
m4_define(gtk_required_version,  1.2.10)

AC_INIT(gnome-python, gnome_python_version,
	[http://bugzilla.gnome.org/enter_bug.cgi?product=gnome-python])
AC_CONFIG_SRCDIR([gnome-python.spec])
AM_CONFIG_HEADER(config.h)

AM_INIT_AUTOMAKE(AC_PACKAGE_TARNAME, AC_PACKAGE_VERSION)
AM_ACLOCAL_INCLUDE(macros)

AC_DISABLE_STATIC
AC_PROG_LIBTOOL

AM_PATH_PYTHON(1.5.2)
AM_CHECK_PYTHON_HEADERS(,[AC_MSG_ERROR(could not find Python headers)])

dnl check if we have Python >= 2.0
AC_MSG_CHECKING(whether $PYTHON version >= 2.0.0)
if $PYTHON -c 'import sys; sys.exit(not (sys.hexversion > 0x20000f0))'; then
  have_python2=yes
else
  have_python2=no
fi
AM_CONDITIONAL(HAVE_PYTHON2, test "$have_python2" = yes)
AC_MSG_RESULT($have_python2)

AM_PATH_GTK(gtk_required_version)
AM_PATH_GDK_IMLIB

GNOME_INIT(applets capplet)

AM_PATH_LIBGLADE(build_gladegnome=true, build_gladegnome=false, gnome)
AM_CONDITIONAL(WITH_GLADEGNOME, $build_gladegnome)

APPLETS_CFLAGS=`$GNOME_CONFIG --cflags applets 2>/dev/null`
CAPPLET_CFLAGS=`$GNOME_CONFIG --cflags capplet 2>/dev/null`
AC_SUBST(APPLETS_CFLAGS)
AC_SUBST(CAPPLET_CFLAGS)

AM_CONDITIONAL(WITH_APPLETS, test -n "$GNOME_APPLETS_LIBS")
AM_CONDITIONAL(WITH_CAPPLET, test -n "$GNOME_CAPPLET_LIBS")

dnl XXX FIX ME when there is a gtkhtml.m4 or gnome-config gtkhtml
dnl AM_PATH_GTKHTML(build_gtkhtml=true, build_gtkhtml=false)
AC_ARG_WITH(gtkhtml,    [  --with-gtkhtml          Build with gtkhtml support],
 build_gtkhtml=yes,
 build_gtkhtml=no)
if test "x$build_gtkhtml" != xno; then
  GTKHTML_CFLAGS=`$GNOME_CONFIG --cflags gtkhtml`
  GTKHTML_LIBS=`$GNOME_CONFIG --libs gtkhtml`
  AC_SUBST(GTKHTML_CFLAGS)
  AC_SUBST(GTKHTML_LIBS)
fi
AM_CONDITIONAL(BUILD_GTKHTML, test "x$build_gtkhtml" != xno)

AM_PATH_GLIB(glib_required_version)

AC_CONFIG_SUBDIRS(pygtk)
AC_CONFIG_FILES([Makefile macros/Makefile
pygnome/Makefile pygnome/generate/Makefile pygnome/gnome/Makefile])
AC_OUTPUT